Acessando externamente RB em conexões ip dinâmico "Dynamic DNS"

Acesso externo pode ser um problema se você não tiver um ip fixo, alguns modos podem ser usados, aqui mesmo já falei sobre o no-ip, que ainda uso, mas agora com este script alem de manter o no-ip funcional também recebo o ip externo por e-mail fora sair fora de falhas, lembre-se de ativar o envio de e-mail dentro de tools.

#insira entre as aspas informações complementares a serem inclusas no e-mail
:local Complemento ""

#Insira o e-mail a receber o bkp
:local Email email@gmail.com.br

#Definindo variaveis
:local IdentityRB [/system identity get name]
:local ModeloRouterBoard [/system routerboard get model]
:local ModRB [/system resource get board-name]
:local VersaoRouterOS [/system resource get version]

# Atualização automático No-IP DNS dinâmico

# --------------- Alterar valores nesta seção para coincidir com sua configuração ------------------
# Informações sobre a conta do usuário No-IP, nome host e interface de entrada de internet
:local noipusername "nome_de_usuario_ou_email_no-ip"
:local noippassword "senha_de_acesso_no_ip"
:local noiphostname "seu.ddns.net"
:local internetinterfece "pppoe-out1"

# Não são necessárias mais alterações
#---------------------------------------------------------------------------------------------------

#Armazenando ip para gerar log
:global previousIP

:if ([/interface get $internetinterfece value-name=running]) do={
 # Obter o IP atual na interface
 :local myip [/ip address get [find interface="$internetinterfece" disabled=no] address]
 # Tirar a máscara de rede do endereço IP
 :for i from=( [:len $myip] - 1) to=0 do={
  :if ( [:pick $myip $i] = "/") do={
   :set myip [:pick $myip 0 $i]
  }
 }
 :if ($myip != $previousIP) do={
  :log info "No-IP: IP atual $myip não é igual ao IP anterior, atualização necessária"
  :set previousIP $myip
  # No URL de atualização observe que o "\3F" é hex para ponto de interrogação (?) e o "\26" é hex para e comercial, Necessário desde então.
  :local url "http://dynupdate.no-ip.com/nic/update?hostname=$noiphostname&myip=$myip"
  :log info "No-IP: Enviando atualização para $noiphostname com IP $myip"
  /tool fetch url=$url user=$noipusername password=$noippassword mode=http keep-result=no
  /tool e-mail send to=$Email subject="IP $IdentityRB $myip" body="Mikrotik $IdentityRB modelo: $ModeloRouterBoard / $ModRB versão RouterOS: $VersaoRouterOS utilizada no gerenciamento de internet $Complemento, esta com este novo endereço externo $myip tambem acessivel em $noiphostname ."
 }
}


Agora agende o script para rodar por exemplo a cada 30 min